$ on control_y then goto chv$user_break
$ set noon
$ write sys$output " "
$ orig_privs        = f$setprv("ALTPRI")
$ chv$say_sub: subroutine
$   write chv$out "''f$time()': " + P1
$   write chv$log "''f$time()': " + P1
$ endsubroutine
$!
$ say="write chv$out f$time() + "": "" +"
$ if f$trnlnm("chv$log_redirect") .eqs "Y"
$ then
$    say="call chv$say_sub"
$ endif
$ write sys$output " "
$ process_priority  = f$getjpi(0,"PRIB")
$ cpu_multiplier    = 1                              ! 1 = VAX, 4 = Alpha/AXP
$ IF F$GETSYI("HW_MODEL") .GT. 1024  THEN cpu_multiplier = 4
$ cpu_rounding      = cpu_multiplier + 1
$ init_counter      = cpu_multiplier * 5300
$ init_loop_maximum = 205
$ start_cputime     = f$getjpi(0,"CPUTIM")
$ loop_index        = 0
$ set noveri
$ 10$:
$     loop_index = loop_index + 1
$     if loop_index .ne. init_loop_maximum then goto 10$
$ end_cputime  = f$getjpi(0,"CPUTIM")
$ init_vups    = ((init_counter / (end_cputime - start_cputime) + -
                    cpu_multiplier) / cpu_rounding) * cpu_rounding
$ loop_maximum = (init_vups * init_loop_maximum) / 10
$ base_counter = (init_counter * init_vups) / 10
$ vups         = 0
$ times_through_loop = 0
$ 20$:
$    times_through_loop = times_through_loop + 1
$    start_cputime = f$getjpi(0,"CPUTIM")
$    loop_index = 0
$    30$:
$        loop_index = loop_index + 1
$        if loop_index .ne. loop_maximum then goto 30$
$    end_cputime = f$getjpi(0,"CPUTIM")
$    new_vups = ((base_counter / (end_cputime - start_cputime) + -
                   cpu_multiplier) / cpu_rounding) * cpu_rounding
$    if  (new_vups .le. (vups + cpu_multiplier + 1))  .and. -
          (new_vups .ge. (vups - (cpu_multiplier + 1)))  then goto 40$
$    vups = new_vups
$    goto 20$
$ 40$:
$ new_privs = f$setprv(orig_privs)
$ set message /nofacility/noidentification/noseverity/notext
$ ASSIGN/SYSTEM/EXEC  'vups'  MACHINE_VUPS_RATING
$ set message /facility/identification/severity/text
$ write sys$output "   Approximate System VUPs Rating :  ", -
                    vups / 10,".", vups - ((vups / 10) * 10)
$ write sys$output " "
$!
$ chv$user_break:
$ exit